using Gtk;
using System;

public class Fluid:TerrPlugin{
	mutable host:TerrHost; public Host:TerrHost { set { host=value; } }
	mutable nr:int;
	//settings
	mutable sC=100;
	mutable sD=10;
	mutable sM=100;
	mutable sT=0.033;
	mutable sInitMin= -500;
	mutable sInitMax=500;
	mutable sIter=50;
	//--------------------------------------------------------------------------------------------------------------
	public Register(n:int):void{
		nr=n;
		def mItem=MenuItem("fluid"); host.MGener.Append(mItem);
			mItem.Activated+=EventHandler(optionsWin);
	}
	//-------------------------------------------------------------------------------------------------------------
	public Run():void{
		host.Start(nr);

		def r=Random();
		def progStep=1/sIter:>double;
		def map=host.HMap; def sizeX=map.SizeX; def sizeY=map.SizeY;

		def mapNew=Terr.Map(sizeX,sizeY,true);
		def mapOld=Terr.Map(sizeX,sizeY,true);

		for (mutable x=0; x<sizeX; x++) for (mutable y=0; y<sizeY; y++) map[x,y]=r.Next(sInitMin,sInitMax);
		for (mutable x=0; x<sizeX; x++) for (mutable y=0; y<sizeY; y++) mapNew[x,y]=map[x,y];
		for (mutable x=0; x<sizeX; x++) for (mutable y=0; y<sizeY; y++) mapOld[x,y]=map[x,y];

		repeat(sIter){ unchecked {
			for (mutable x=0; x<sizeX; x++) for (mutable y=0; y<sizeY; y++)
				mapNew[x,y]=((4-8*sC*sC*sT*sT/(sD*sD))/(sM*sT+2))*map[x,y]+((sM*sT-2)/(sM*sT+2))*mapOld[x,y]+((2*sC*sC*sT*sT/sD*sD)/(sM*sT+2))*(map[x+1,y]+map[x-1,y]+map[x,y+1]+map[x,y-1]);
			for (mutable x=0; x<sizeX; x++) for (mutable y=0; y<sizeY; y++) mapOld[x,y]=map[x,y];
			for (mutable x=0; x<sizeX; x++) for (mutable y=0; y<sizeY; y++) map[x,y]=mapNew[x,y];
			host.ProgBar.FractionAddResp(progStep);
		}}

		host.Update();
	}
	//-------------------------------------------------------------------------------------------------------------
	private optionsWin(_o:object,_e:EventArgs):void{
		def win=Window("fluid");
			win.BorderWidth=5;
		def tips=Tooltips();
		def whole=VBox(false,10); win.Add(whole);

		def sett=VBox(false,10); whole.PackStart(sett);
			def cHBox=HBox(false,10); sett.PackStart(cHBox);
				def cLab=Label("c:"); cHBox.PackStart(cLab);
				def cSpin=SpinButton(0.0,300,1.0); cHBox.PackStart(cSpin);
					tips.SetTip(cSpin,"please see http://heightmapper.sourceforge.net/plugins/fluid.php","");
					cSpin.Value=sC;
					cSpin.ValueChanged+=fun(_) { sC=cSpin.ValueAsInt; }
			def dHBox=HBox(false,10); sett.PackStart(dHBox);
				def dLab=Label("d:"); dHBox.PackStart(dLab);
				def dSpin=SpinButton(0.0,100,1.0); dHBox.PackStart(dSpin);
					tips.SetTip(dSpin,"please see http://heightmapper.sourceforge.net/plugins/fluid.php","");
					dSpin.Value=sD;
					dSpin.ValueChanged+=fun(_) { sD=dSpin.ValueAsInt; }
			def mHBox=HBox(false,10); sett.PackStart(mHBox);
				def mLab=Label("mi:"); mHBox.PackStart(mLab);
				def mSpin=SpinButton(0.0,300,1.0); mHBox.PackStart(mSpin);
					tips.SetTip(mSpin,"please see http://heightmapper.sourceforge.net/plugins/fluid.php","");
					mSpin.Value=sM;
					mSpin.ValueChanged+=fun(_) { sM=mSpin.ValueAsInt; }
			def tHBox=HBox(false,10); sett.PackStart(tHBox);
				def tLab=Label("t:"); tHBox.PackStart(tLab);
				def tSpin=SpinButton(0.0,1.0,0.001); tHBox.PackStart(tSpin);
					tips.SetTip(tSpin,"please see http://heightmapper.sourceforge.net/plugins/fluid.php","");
					tSpin.Value=sT;
					tSpin.ValueChanged+=fun(_) { sT=tSpin.ValueAsInt; }
			def initHBox=HBox(false,10); sett.PackStart(initHBox);
				def init1Lab=Label("initial:"); initHBox.PackStart(init1Lab);
				def initMinSpin=SpinButton(-2000.0,0.0,1.0); initHBox.PackStart(initMinSpin);
					tips.SetTip(initMinSpin,"the minimum of initial values","");
					initMinSpin.Value=sInitMin;
					initMinSpin.ValueChanged+=fun(_) { sInitMin=initMinSpin.ValueAsInt; }
				def init2Lab=Label("to"); initHBox.PackStart(init2Lab);
				def initMaxSpin=SpinButton(0.0,2000,1.0); initHBox.PackStart(initMaxSpin);
					tips.SetTip(initMaxSpin,"the maximum of initial values","");
					initMaxSpin.Value=sInitMax;
					initMaxSpin.ValueChanged+=fun(_) { sInitMax=initMaxSpin.ValueAsInt; }
			def iterHBox=HBox(false,10); sett.PackStart(iterHBox);
				def iterLab=Label("iterations:"); iterHBox.PackStart(iterLab);
				def iterSpin=SpinButton(0.0,200,1.0); iterHBox.PackStart(iterSpin);
					tips.SetTip(iterSpin,"the number of iterations ","");
					iterSpin.Value=sIter;
					iterSpin.ValueChanged+=fun(_) { sIter=iterSpin.ValueAsInt; }

		def buttBox=HBox(false,10); whole.PackStart(buttBox);
			def aboutButt=Button("about"); buttBox.PackStart(aboutButt);
				aboutButt.Clicked+=EventHandler(aboutButtHandler);
			def cancelButt=Button("cancel"); buttBox.PackStart(cancelButt);
				 cancelButt.Clicked+=fun(_) { win.Destroy(); }
			def okButt=Button("ok"); buttBox.PackStart(okButt);
				okButt.Clicked+=fun(_) { Run(); win.Destroy(); }

		win.ShowAll();
	}
	//-------------------------------------------------------------------------------------------------------------
	private aboutButtHandler(_o:object,_e:EventArgs):void{
		def dial=MessageDialog(null,DialogFlags.Modal,MessageType.Info,ButtonsType.Ok,"fluid algorithm plugin 0.2:0.3 by caminoix, 27.08.2006\n\nfor more information on the algorithm please see\nhttp://heightmapper.sourceforge.net/plugins/fluid.php");
		_=dial.Run();
		dial.Destroy();
	}
}