using Gtk;
using System;

public class Hills:TerrPlugin{
	mutable host:TerrHost; public Host:TerrHost { set { host=value; } }
	mutable nr:int;
	//settings
	mutable sCircles=1000;
	mutable sEllipse=false;
	mutable sMaxRad=25;
	//--------------------------------------------------------------------------------------------------------------
	public Register(num:int):void{
		nr=num;
		def mItem=MenuItem("hills"); host.MGener.Append(mItem);
			mItem.Activated+=EventHandler(optionsWin);
	}
	//--------------------------------------------------------------------------------------------------------------
	public Run():void{
		host.Start(nr);

		def r=Random();
		def progStep=100/(sCircles*100):>double;
		def map=host.HMap; def sizeX=map.SizeX; def sizeY=map.SizeY;
		for (mutable x=0; x<sizeX; x++) for (mutable y=0; y<sizeY; y++) map[x,y]=0.0;

		for (mutable x=0; x<sizeX; x++) for (mutable y=0; y<sizeY; y++) map[x,y]=0.0;

		repeat(sCircles){
			def radX=r.Next(sMaxRad); mutable radY=radX; when (sEllipse) radY=r.Next(sMaxRad);
			def x=r.Next(-radX,sizeX+radX); def y=r.Next(-radY,sizeY+radY);
			for (mutable i=x-radX; i<x+radX; ++i) for (mutable ii=y-radY; ii<y+radY; ++ii){
				def tmp=radX*radY-((i-x)*(i-x)+(ii-y)*(ii-y));
				when (tmp>=0)
					when ((i>=0)&&(i<sizeX)&&(ii>=0)&&(ii<sizeY)) map[i,ii]+=tmp;
			}
			host.ProgBar.FractionAddResp(progStep);
		}


		host.Update();
	}
	//--------------------------------------------------------------------------------------------------------------
	private optionsWin(_o:object,_e:EventArgs):void{
		def win=Window("hills");
			win.BorderWidth=5;
		def tips=Tooltips();
		def whole=VBox(false,10); win.Add(whole);

		def sett=VBox(false,10); whole.PackStart(sett);
			def circlesHBox=HBox(false,10); sett.PackStart(circlesHBox);
				def circlesLab=Label("circles:"); circlesHBox.PackStart(circlesLab);
				def circlesSpin=SpinButton(0.0,10000,1.0); circlesHBox.PackStart(circlesSpin);
					tips.SetTip(circlesSpin,"number of circles","");
					circlesSpin.Value=sCircles;
					circlesSpin.ValueChanged+=fun(_) { sCircles=circlesSpin.ValueAsInt; }
			def ellipseHBox=HBox(false,10); sett.PackStart(ellipseHBox);
				def ellipseLab=Label("ellipses:"); ellipseHBox.PackStart(ellipseLab);
				def ellipseChck=CheckButton("off"); ellipseHBox.PackStart(ellipseChck);
					ellipseChck.Toggled+=fun(_){
						if (ellipseChck.Label=="off"){
							sEllipse=true;
							ellipseChck.Label="on";
						} else {
							sEllipse=false;
							ellipseChck.Label="off";
						}
					}
			def maxRadHBox=HBox(false,10); sett.PackStart(maxRadHBox);
				def maxRadLab=Label("maxRad:"); maxRadHBox.PackStart(maxRadLab);
				def maxRadSpin=SpinButton(0.0,10000,1.0); maxRadHBox.PackStart(maxRadSpin);
					tips.SetTip(maxRadSpin,"number of maxRad","");
					maxRadSpin.Value=sMaxRad;
					maxRadSpin.ValueChanged+=fun(_) { sMaxRad=maxRadSpin.ValueAsInt; }

		def buttBox=HBox(false,10); whole.PackStart(buttBox);
			def aboutButt=Button("about"); buttBox.PackStart(aboutButt);
				aboutButt.Clicked+=EventHandler(aboutButtHandler);
			def cancelButt=Button("cancel"); buttBox.PackStart(cancelButt);
				 cancelButt.Clicked+=fun(_) { win.Destroy(); }
			def okButt=Button("ok"); buttBox.PackStart(okButt);
				okButt.Clicked+=fun(_) { Run(); win.Destroy(); }

		win.ShowAll();
	}
	//--------------------------------------------------------------------------------------------------------------
	private aboutButtHandler(_o:object,_e:EventArgs):void{
		def dial=MessageDialog(null,DialogFlags.Modal,MessageType.Info,ButtonsType.Ok,"hills algorithm plugin 0.3:0.3 by caminoix, 27.08.2006\n\nfor more information on the algorithm please see\nhttp://terraineer.sourceforge.net/plugins/hills.php");
		_=dial.Run();
		dial.Destroy();
	}
}